wierd lang IDE

Basic Syntax

One command per line. Comments start with //.

Chain commands on one line with &:

print Hello world
var x 10          // set x
print $x & var x 20 // chain

Inside fn/define bodies use && to chain instead — & is reserved for control flow bodies there.

Value Prefixes

Every value is a space-separated token. Its first character tells the interpreter how to evaluate it:

$name          read variable
^arr|0         array element (1-indexed)
^arr|          entire array
(5+$x)         math expression
{randint|1|6}  inline returnable
*$notavar      literal — skip evaluation
_              a single space

Anything with no prefix is returned as-is.

Variables

var name value

Creates or overwrites. Value can be anything:

var x 10
var msg Hello there
var result ($x+5)
var roll {randint|1|6}
var copy $x

Variable names can themselves be variables — $$which evaluates $which first then uses that as the variable name:

var which score
var score 99
print $$which    // prints 99

Delete a variable:

trash var x

Arrays

array name item1 item2 item3

Items are 1-indexed (index 0 is the name internally).

array fruits apple banana cherry
print ^fruits|1     // apple
print ^fruits|      // whole array

Modifying:

append fruits mango      // add to end
insert fruits 2 kiwi     // replace index 2
trash item fruits|2      // delete index 2
trash array fruits       // delete array

Dynamic index:

var i 1
print ^fruits|$i    // index from var

Iterate:

for item in fruits print $item

Functions without args

fn + run. No parameters.

fn greet print Hello && print World
run greet

Use && between statements in the body.
Use & only inside loop/if bodies within the function.

fn count var i 0 && while $i < 3 print $i & var i ($i+1)
run count

Functions with args

define + call. Params separated by |:

define add a|b print ($a+$b)
call add 5 3

No params — use | alone:

define shout | print HELLO
call shout

Use && between statements in the body.
Use & only inside loop/if bodies within the function.

define countdown n var i $n && while $i > 0 print $i & var i ($i-1)
call countdown 5

if val1 op val2 command

Runs command if condition is true. Chain with &:

if $x > 10 print big
if $name == oyon print hi oyon & var found true

No else — simulate with opposite conditions:

if $x > 5 print big
if $x <= 5 print small

Operators: == != < > <= >=

while

while val1 op val2 command

Loops while condition is true. Chain body commands with &:

var i 0
while $i < 5 print $i & var i ($i+1)

Hard limit of 10000 iterations — after that it stops with an error.

Condition re-evaluates every iteration so variable updates take effect.

for / repeat

for — iterate over every item in an array:

array names Alice Bob Charlie
for name in names print Hello $name

Chain body commands with &:

for x in nums print $x & var total ($total+$x)

repeat — run a command N times:

repeat 5 print hi
repeat $n print again     // n from var

Math

Wrap in (). Operators: + - * /
Evaluated strictly left-to-right — no precedence:

(10+5)        // 15
($x*$y)       // x times y
(2+3*4)       // 20, not 14
($a+$b-1)     // chained

Use in var, if, while, print — anywhere a value is accepted:

var area ($w*$h)
if ($x*2) > 10 print large

Inline Returnables { }

Call a function inline and use its return value. Syntax: {func|arg1|arg2}

{randint|1|6}      // random 1-6
{concat|$a|_|$b}   // join strings

Use anywhere a value is accepted:

var dice {randint|1|6}
if {randint|0|1} == 1 print heads

Input / Output

print — output values, space-separated:

print Hello $name
print Result is ($x+$y)

input — browser prompt, stores result in variable:

input name What is your name?
print Hello $name

First arg is the variable. Everything after is the prompt text.

⚠ Don't attach punctuation to $variables in print — $name! looks up "name!" not "name".

String Ops

concat — join strings into a variable:

concat full $first _ $last
print $full

Use _ for a space between parts. Or use the inline returnable:

var full {concat|$first|_|$last}

Utilities

randint x 1 100    // random int → var
sleep 2             // pause 2 seconds
clear               // clear terminal
terminate           // stop program

Token Gotchas

These characters have special meaning — using them wrong in print will break output or crash:

$name!   // looks up "name!" not "name"
(hello)  // tries to do math, crashes
{word}   // tries to call a function
^thing   // tries array access
*hello   // prints "hello", * disappears
_        // becomes a space

Fix: put a space before any punctuation after a variable, or use * to force literal.

main.wierd

LN 1, COL 1

> wierd lang loaded successfully